GeezerVison is showing github.com — Editor/scripts/code-cli.bat at Current · DependencyCodeEditorLand/Editor

Expand file tree

code-cli.bat

Copy path

More file actions

45 lines (33 loc) · 949 Bytes

Copy path

45 lines (33 loc) · 949 Bytes

Copy raw file

Download raw file

Open symbols panel

Edit and raw actions

@echo off

setlocal

title VSCode Dev

pushd %~dp0..

:: Get electron, compile, built-in extensions

if "%VSCODE_SKIP_PRELAUNCH%"=="" node build/lib/preLaunch.ts

set "NAMESHORT="

for /f "tokens=2 delims=:," %%a in ('findstr /R /C:"\"nameShort\":.*" product.json') do if not defined NAMESHORT set "NAMESHORT=%%~a"

set NAMESHORT=%NAMESHORT: "=%

set NAMESHORT=%NAMESHORT:"=%.exe

set CODE=".build\electron\%NAMESHORT%"

:: Manage built-in extensions

if "%~1"=="--builtin" goto builtin

:: Configuration

set ELECTRON_RUN_AS_NODE=1

set NODE_ENV=development

set VSCODE_DEV=1

set ELECTRON_ENABLE_LOGGING=1

set ELECTRON_ENABLE_STACK_DUMPING=1

set DISABLE_TEST_EXTENSION="--disable-extension=vscode.vscode-api-tests"

for %%A in (%*) do (

if "%%~A"=="--extensionTestsPath" (

set DISABLE_TEST_EXTENSION=""

)

:: Launch Code

%CODE% --inspect=5874 out\cli.js %~dp0.. %DISABLE_TEST_EXTENSION% %*

goto end

:builtin

%CODE% build/builtin

:end

popd

endlocal