Interactive programming with F#

F# Interactive (dotnet fsi) is used to run F# code interactively at the console, or to execute F# scripts. In other words, F# interactive executes a REPL (Read, Evaluate, Print Loop) for F#.

To run F# Interactive from the console, run dotnet fsi. You will find dotnet fsi in any .NET SDK.

For information about available command-line options, see F# Interactive Options.

Executing code directly in F# Interactive

Because F# Interactive is a REPL (read-eval-print loop), you can execute code interactively in it. Here is an example of an interactive session after executing dotnet fsi from the command line:

Microsoft (R) F# Interactive version 11.0.0.0 for F# 5.0
Copyright (c) Microsoft Corporation. All Rights Reserved.

For help type #help;;

> let square x = x *  x;;
val square : x:int -> int

> square 12;;
val it : int = 144

> printfn "Hello, FSI!"
- ;;
Hello, FSI!
val it : unit = ()

You'll notice two main things:

1. All code must be terminated with a double semicolon (;;) to be evaluated
2. Code is evaluated and stored in an it value. You can reference it interactively.

F# Interactive also supports multi-line input. You just need to terminate your submission with a double semicolon (;;). Consider the following snippet that has been pasted into and evaluated by F# Interactive:

> let getOddSquares xs =
-     xs
-     |> List.filter (fun x -> x % 2 <> 0)
-     |> List.map (fun x -> x * x)
-
- printfn "%A" (getOddSquares [1..10]);;
[1; 9; 25; 49; 81]
val getOddSquares : xs:int list -> int list
val it : unit = ()

>

The code's formatting is preserved, and there is a double semicolon (;;) terminating the input. F# Interactive then evaluated the code and printed the results!

Core build and asynchronous disposal

For asynchronous disposal in task expressions, update to the F# 11 toolset with the modern Core packaging fix. An application package reference doesn't change FSI's bundled Core.

Display version information

Starting with F# 11, enter #version;; to display version information for the current F# Interactive session without restarting it:

#version;;

Include this output when you report a compiler or scripting problem.

Scripting with F#

Evaluating code interactively in F# Interactive can be a great learning tool, but you'll quickly find that it's not as productive as writing code in a normal editor. To support normal code editing, you can write F# scripts.

Scripts use the file extension .fsx. Instead of compiling source code and then later running the compiled assembly, you can just run dotnet fsi and specify the filename of the script, and F# Interactive reads the code and executes it in real time. For example, consider the following script called Script.fsx:

let getOddSquares xs =
    xs
    |> List.filter (fun x -> x % 2 <> 0)
    |> List.map (fun x -> x * x)

printfn "%A" (getOddSquares [1..10])

When this file is created in your machine, you can run it with dotnet fsi and see the output directly in your terminal window:

dotnet fsi Script.fsx
[1; 9; 25; 49; 81]

Executing Scripts with a Shebang

To make F# scripts executable without explicitly invoking dotnet fsi, you can use a shebang line at the top of the script. This enables you to run the script directly from the terminal, like a shell script.

For example, create a script file called ExecutableScript.fsx with the following content:

#!/usr/bin/env -S dotnet fsi

let getOddSquares xs =
    xs
    |> List.filter (fun x -> x % 2 <> 0)
    |> List.map (fun x -> x * x)

printfn "%A" (getOddSquares [1..10])

1. Make the Script Executable: Use the chmod command to make the script executable:

   chmod +x ExecutableScript.fsx
   

2. Run the Script Directly: Now, you can execute the script directly from the terminal:

   ./ExecutableScript.fsx
   

Note: Shebang functionality (#!) is specific to Unix-like systems such as Linux and MacOS. On Windows, you can execute scripts using dotnet fsi Script.fsx directly in the terminal or command prompt.

This feature allows for a more seamless experience when working with F# scripts in environments like Linux and macOS.

F# scripting is natively supported in Visual Studio and Visual Studio Code.

Referencing packages in F# Interactive

Since 5.0 release of the language, F# Interactive supports referencing packages through an extensibility mechanism; out of the box, it can reference NuGet packages with the #r "nuget:" syntax and an optional version:

#r "nuget: Newtonsoft.Json"
open Newtonsoft.Json

let data = {| Name = "Don Syme"; Occupation = "F# Creator" |}
JsonConvert.SerializeObject(data)

If a version is not specified, the highest available non-preview package is taken. To reference a specific version, introduce the version via a comma. This can be handy when referencing a preview version of a package. For example, consider this script using a preview version of DiffSharp:

#r "nuget: DiffSharp-lite, 1.0.0-preview-328097867"
open DiffSharp

// A 1D tensor
let t1 = dsharp.tensor [ 0.0 .. 0.2 .. 1.0 ]

// A 2x2 tensor
let t2 = dsharp.tensor [ [ 0; 1 ]; [ 2; 2 ] ]

// Define a scalar-to-scalar function
let f (x: Tensor) = sin (sqrt x)

printfn $"{f (dsharp.tensor 1.2)}"

By default, #r "nuget: ...." doesn't use build targets from the package being referenced during restore. The usepackagetargets option enables the use of these build targets when required. Only add usepackagetargets=true if the referenced package was authored to require it during restore. Examples:

// load fsharp.data nugetpackage and consume buildtargets from fsharp.data package during restore.
#r "nuget:fsharp.data,usepackagetargets=true"
#r "nuget:fsharp.data,6.6.0,usepackagetargets=false"
#r "nuget:fsharp.data,6.6.0,usepackagetargets=true"

Specifying a package source

You can also specify a package source with the #i command. The following examples specify remote and local sources:

#i "nuget: https://my-remote-package-source/index.json"
#i """nuget: C:\path\to\my\local\source"""
#i "nuget: /Users/username/path/to/my/local/source"
#i "nuget: /home/username/path/to/my/local/source"

This tells the resolution engine to take into account the remote and/or local sources added to a script.

You can specify as many package sources as you like in a script.

let localSource = System.IO.Path.Combine(__SOURCE_DIRECTORY__, "relative/path/to/my/local/source")
#i $"""nuget: {localSource}"""

Referencing assemblies on disk with F# interactive

Alternatively, if you have an assembly on disk and wish to reference that in a script, you can use the #r syntax to specify an assembly. Consider the following code in a project compiled into MyAssembly.dll:

// MyAssembly.fs
module MyAssembly
let myFunction x y = x + 2 * y

Once compiled, you can reference it in a file called Script.fsx like so:

#r "path/to/MyAssembly.dll"

printfn $"{MyAssembly.myFunction 10 40}"

The output is as follows:

dotnet fsi Script.fsx
90

You can specify as many assembly references as you like in a script.

Loading other scripts

When scripting, it can often be helpful to use different scripts for different tasks. Sometimes you may want to reuse code from one script in another. Rather than copy-pasting its contents into your file, you can simply load and evaluate it with #load.

Consider the following Script1.fsx:

let square x = x * x

And the consuming file, Script2.fsx:

#load "Script1.fsx"
open Script1

printfn $"%d{square 12}"

You can evaluate Script2.fsx like so:

dotnet fsi Script2.fsx
144

You can specify as many #load directives as you like in a script.

module MyScriptLibrary

Using the fsi object in F# code

F# scripts have access to a custom fsi object that represents the F# Interactive session. It allows you to customize things like output formatting. It is also how you can access command-line arguments.

The following example shows how to get and use command-line arguments:

let args = fsi.CommandLineArgs

for arg in args do
    printfn $"{arg}"

When evaluated, it prints all arguments. The first argument is always the name of the script that is evaluated:

dotnet fsi Script1.fsx hello world from fsi
Script1.fsx
hello
world
from
fsi

You can also use System.Environment.GetCommandLineArgs() to access the same arguments.

F# Interactive directive reference

The #r and #load directives seen previously are only available in F# Interactive. There are several directives only available in F# Interactive:

[^1]: More about F# Interactive extensions.

When you specify files or paths in F# Interactive, a string literal is expected. Therefore, files and paths must be in quotation marks, and the usual escape characters apply. You can use the @ character to cause F# Interactive to interpret a string that contains a path as a verbatim string. This causes F# Interactive to ignore any escape characters.

For other cases, quotation marks are optional, starting with F# 9.

Extended #help directive

The #help directive now supports displaying documentation for specific functions. You can pass the name of the function directly to retrieve details.

#help List.map;;

The output is as follows:

Description:
Builds a new collection whose elements are the results of applying the given function
to each of the elements of the collection.

Parameters:
- mapping: The function to transform elements from the input list.
- list: The input list.

Returns:
The list of transformed elements.

Examples:
let inputs = [ "a"; "bbb"; "cc" ]

inputs |> List.map (fun x -> x.Length)
// Evaluates to [ 1; 3; 2 ]

Full name: Microsoft.FSharp.Collections.ListModule.map
Assembly: FSharp.Core.dll

This enhancement makes it easier to explore and understand F# libraries interactively.

For more details, refer to the official devblog.

Interactive and compiled preprocessor directives

When you compile code in F# Interactive, whether you are running interactively or running a script, the symbol INTERACTIVE is defined. When you compile code in the compiler, the symbol COMPILED is defined. Thus, if code needs to be different in compiled and interactive modes, you can use these preprocessor directives for conditional compilation to determine which to use. For example:

#if INTERACTIVE
// Some code that executes only in FSI
// ...
#endif

Using F# Interactive in Visual Studio

To run F# Interactive through Visual Studio, you can click the appropriate toolbar button labeled F# Interactive, or use the keys Ctrl+Alt+F. Doing this will open the interactive window, a tool window running an F# Interactive session. You can also select some code that you want to run in the interactive window and hit the key combination Alt+Enter. F# Interactive starts in a tool window labeled F# Interactive. When you use this key combination, make sure that the editor window has the focus.

Whether you are using the console or Visual Studio, a command prompt appears and the interpreter awaits your input. You can enter code just as you would in a code file. To compile and execute the code, enter two semicolons (;;) to terminate a line or several lines of input.

F# Interactive attempts to compile the code and, if successful, it executes the code and prints the signature of the types and values that it compiled. If errors occur, the interpreter prints the error messages.

Code entered in the same session has access to any constructs entered previously, so you can build up programs. An extensive buffer in the tool window allows you to copy the code into a file if needed.

When run in Visual Studio, F# Interactive runs independently of your project, so, for example, you cannot use constructs defined in your project in F# Interactive unless you copy the code for the function into the interactive window.

You can control the F# Interactive command-line arguments (options) by adjusting the settings. On the Tools menu, select Options..., and then expand F# Tools. The two settings that you can change are the F# Interactive options and the 64-bit F# Interactive setting, which is relevant only if you are running F# Interactive on a 64-bit machine. This setting determines whether you want to run the dedicated 64-bit version of fsi.exe or fsianycpu.exe, which uses the machine architecture to determine whether to run as a 32-bit or 64-bit process.

Related articles