GeezerVisonThe World Wide Web, restored to 800 pixels of glory. | |||||||||||||||||||||||||||||||
| Home|About|Gaming cabinet|Archives|How it works|Starter sites | |||||||||||||||||||||||||||||||
GeezerVison is showing reference.wolfram.com — NondimensionalizationTransform—Wolfram Documentation NondimensionalizationTransform[eq,ovars,fvars] nondimensionalizes eq, replacing original variables ovars with the variables fvars. NondimensionalizationTransform[eq,ovars,fvars,prop] returns a property associated with the nondimensionalization of eq. Details and Options
Examples
Basic Examples
Scope
Options
GeneratedParameters
GeneratedQuantityMagnitudes
IncludeQuantities
UnitSystem
Applications
Properties & Relations
Possible Issues
Neat Examples
See Also
Related Guides
History
Cite this Page
NondimensionalizationTransformNondimensionalizationTransform[eq,ovars,fvars] nondimensionalizes eq, replacing original variables ovars with the variables fvars. NondimensionalizationTransform[eq,ovars,fvars,prop] returns a property associated with the nondimensionalization of eq. Details and Options
Examplesopen all close allBasic Examples (2)Remove dimensions from the driven oscillator equation: NondimensionalizationTransform[ω x[t] + a Derivative[1][x][t] == A f[t], {x, t, f}, {y, u, g}]Compute the replacement rules for the wave equation that yields a dimensionless form: waveequation = u^(0, 2)[x, t] == cp^2 u^(2, 0)[x, t];NondimensionalizationTransform[waveequation, {u, x, t}, {v, y, u}, "NondimensionalizationRules"]Scope (4)Solve for the nondimensionalized form of the quantum harmonic oscillator: odeHO = (1/2) m x^2 ω^2 ψ[x] + ((Quantity[-(1/2), "ReducedPlanckConstant"^2]) Derivative[2][ψ][x]/m) == E ψ[x];NondimensionalizationTransform[odeHO, {ψ, x} , {Ψ, ξ}]Examine the replacement rules for this transformation: NondimensionalizationTransform[odeHO, {ψ, x}, {Ψ, ξ}, "NondimensionalizationMultipliers"]Specify a replacement variable for energy to replace C[1] in the solution: NondimensionalizationTransform[odeHO, {ψ, x, E}, {Ψ, ξ, e}]Nondimensionalize algebraic equations: accelerationSpeedDistance = s == s0 + (1/2) a t^2 + t v;NondimensionalizationTransform[accelerationSpeedDistance, {a, v, t, s0}, {b, w, u, d0}]Examine the solutions for driven RC and LRC circuits: τ = QuantityVariable["t", "Time"];
q = QuantityVariable["Q", "ElectricCharge"];
v = QuantityVariable["V", "ElectricPotential"];
r = QuantityVariable["R", "ElectricResistance"];
c = QuantityVariable["C", "ElectricCapacitance"];
l = QuantityVariable["L", "MagneticInductance"];odeRC = r q'[τ] + q[τ] / c == v[τ]odeLRC = l q''[τ] + r q'[τ] + q[τ] / c == v[τ]NondimensionalizationTransform[odeRC, {q, v, τ}, {x, f, u}]Find the properties available: NondimensionalizationTransform["Properties"]Compute all properties of this transformation: NondimensionalizationTransform[odeRC, {q, v, τ}, {x, f, u}, "PropertyAssociation"]Examine the LRC circuit nondimensionalization: NondimensionalizationTransform[odeLRC, {q, v, τ}, {x, f, u}, "PropertyAssociation"]Remove dimensions from lists of equations at once: ψ = QuantityVariable["ψ", "Length" ^ (-1 / 2)];
ψaux = QuantityVariable[Subscript["ψ", "aux"], "Length" ^ (-1 / 2) / "Length"];
𝓍 = QuantityVariable["x", "Length"];
𝓂 = QuantityVariable["m", "Mass"];
ω = QuantityVariable["ω", "Frequency"];
ℰ = QuantityVariable["E", "Energy"];odeHO = {-Quantity[1, "ReducedPlanckConstant"] ^ 2 / (2 𝓂) ψaux'[𝓍] + 1 / 2 𝓂 ω ^ 2 𝓍 ^ 2 ψ[𝓍] == ℰ ψ[𝓍], ψaux[𝓍] == ψ'[𝓍]};NondimensionalizationTransform[odeHO, {ψ, ψaux, 𝓍}, {Ψ, Ψaux, ξ}]Options (5)GeneratedParameters (1)Control how introduced parameters are named: eq = (1/2) m x^2 ω^2 ψ[x] + ((Quantity[-(1/2), "ReducedPlanckConstant"^2]) Derivative[2][ψ][x]/m) == E ψ[x];NondimensionalizationTransform[eq, {ψ, x}, {Ψ, ξ}, GeneratedParameters -> Z]Avoid GeneratedParameters entirely by specifying replacements for more QuantityVariable objects: NondimensionalizationTransform[eq, {ψ, x, E} , {Ψ, ξ, e}, GeneratedParameters -> Z]GeneratedQuantityMagnitudes (1)Adjust the names of introduced constants: waveEquation = u^(0, 2)[x, t] == cp^2 u^(2, 0)[x, t];
NondimensionalizationTransform[waveEquation, {u, x, t}, {v, y, u}, "NondimensionalizationMultipliers", GeneratedQuantityMagnitudes -> "foo"]Alternatively, specify additional quantities to include when solving for a dimensionless form: NondimensionalizationTransform[waveEquation, {u, x, t}, {v, y, u}, "NondimensionalizationMultipliers", IncludeQuantities -> {Quantity[1, "Atmospheres"], Quantity[1, "PlanckLength"]}]IncludeQuantities (1)Add additional quantities that can be used to solve for a dimensionless form: waveEquation = u^(0, 2)[x, t] == cp^2 u^(2, 0)[x, t];
NondimensionalizationTransform[waveEquation, {u, x, t}, {v, y, u}, IncludeQuantities -> {"Seconds"}]UnitSystem (2)Simplify Newton's law of gravitation using Planck units: F = QuantityVariable["F", "Force"];
m1 = QuantityVariable[Subscript["m", 1], "Mass"];
m2 = QuantityVariable[Subscript["m", 2], "Mass"];
r = QuantityVariable["r", "Length"];
G = Quantity[1, "GravitationalConstant"];grav = F == G m1 m2 / r ^ 2NondimensionalizationTransform[grav, {F, m1, m2, r}, {f, mp1, mp2, ρ}, "NondimensionalizationMultipliers", UnitSystem -> "PlanckUnits"]Compare against the standard method solution: NondimensionalizationTransform[grav, {F, m1, m2, r}, {f, mp1, mp2, ρ}, "NondimensionalizationMultipliers"]Explore the available natural unit systems and the values of their units: SlideView[{...}]Applications (4)Nondimensionalize Poisson's equation for gravity: x = QuantityVariable["x", "Length"];
y = QuantityVariable["y", "Length"];
z = QuantityVariable["z", "Length"];
g = QuantityVariable["ϕ", "GravitationalPotential"];
ρ = QuantityVariable["ρ", "MassDensity"];peq = Laplacian[g[x, y, z], {x, y, z}] == 4 Pi Quantity[1, "GravitationalConstant"]ρNondimensionalizationTransform[peq, {g, ρ}, {γ, r}]Examine the dimensionless Klein–Gordon equation: x = QuantityVariable["x", "Length"];
y = QuantityVariable["y", "Length"];
z = QuantityVariable["z", "Length"];
t = QuantityVariable["t", "Time"];
m = QuantityVariable["m", "Mass"];
ψ = QuantityVariable["ψ", "Length" ^ (-1 / 2)];eq = 1 / Quantity[1, "SpeedOfLight"] ^ 2D[ψ[x, y, z, t], t, t] - Laplacian[ψ[x, y, z, t], {x, y, z}] + m ^ 2 Quantity[1, "SpeedOfLight"^2] / Quantity[1, "ReducedPlanckConstant"^2]ψ[x, y, z, t]NondimensionalizationTransform[eq, {ψ, t}, {Ψ, τ}]Simplify the result further by specifying replacement variables for most of the QuantityVariable objects: NondimensionalizationTransform[eq, {ψ, t, x, y, z}, {Ψ, τ, ξ, η, ζ}]Compute the dimensionless form of physical systems: eq = Expand /@ Entity["PhysicalSystem", "VanDerWaalsGas"][EntityProperty["PhysicalSystem", "EquationOfState"]]NondimensionalizationTransform[eq, {p, V, T, n}, {𝓅, 𝓋, 𝓉, ν}]Nondimensionalize a one-dimensional Schrödinger's equation using Planck units and Hartree units: r = QuantityVariable["r", "Length"];
t = QuantityVariable["t", "Time"];
me = Quantity[1, "ElectronMass"];
ψ = QuantityVariable["ψ", "Length" ^ (-1 / 2)];
e0 = Quantity[4 Pi, "ElectricConstant"];
e = Quantity[1, "ElementaryCharge"];eq = I Quantity[1, "ReducedPlanckConstant"]D[ψ[r, t], t] == -Quantity[1, "ReducedPlanckConstant"] ^ 2 / (2 me)D[ψ[r, t], {r, 2}] + e ^ 2 / (e0 r) ψ[r, t]NondimensionalizationTransform[eq, {ψ, r, t}, {Ψ, ρ, τ}, UnitSystem -> "PlanckUnits"]Examine the result to check that it is dimensionless: % /. q_Quantity :> UnitConvert[q, "SIBase"]Compare to the solution in Hartree atomic units: NondimensionalizationTransform[eq, {ψ, r, t}, {Ψ, ρ, τ}, UnitSystem -> "HartreeAtomicUnits"]Properties & Relations (1)DimensionalCombinations derives dimensionless combinations of QuantityVariable objects: s = QuantityVariable["s", "Length"];
s0 = QuantityVariable["s0", "Length"];
a = QuantityVariable["a", "Acceleration"];
t = QuantityVariable["t", "Time"];
v = QuantityVariable["v", "Speed"];DimensionalCombinations[{s, s0, a, t, v}, GeneratedParameters -> None]Compare to the dimensionalization rules for an equation for linear motion: accelerationSpeedDistance = s == s0 + (1/2) a t^2 + t v;NondimensionalizationTransform[accelerationSpeedDistance, {a, t, s0}, {b, u, d0}, "DimensionalizationRules"]Possible Issues (3)Equations must be dimensionally balanced: Q1 = QuantityVariable["Q", "ElectricCharge"];
t1 = QuantityVariable["t", "Time"];NondimensionalizationTransform[Q1 - t1 == 0, {Q1, t1}, {Q2, t2}]
Replacement variables must be dimensionless: NondimensionalizationTransform[(d/t) == v, {d, t}, {Quantity[1, "Meters"], t2}]
Supplied variables should be present within the equation: NondimensionalizationTransform[(d/t) == v, {d, QuantityVariable["Q", "ElectricCharge"]}, {d2, Q2}]
Neat Examples (1)Transform Coulomb's law and Newton's law of gravitation using different sets of natural units: naturalunits = {"PlanckUnits", "HartreeAtomicUnits", "RydbergAtomicUnits", "LorentzHeavisideNaturalUnits", "GaussianNaturalUnits"};cleq = First@FormulaData["CoulombsLaw"]nlogeq = FormulaData["NewtonsLawOfUniversalGravitation"]coulomb = NondimensionalizationTransform[cleq, {F, Subscript[Q, 1], Subscript[Q, 2], r}, {f, q1, q2, ρ}, UnitSystem -> #]& /@ naturalunits;
gravity = NondimensionalizationTransform[nlogeq, {F, Subscript[m, 1], Subscript[m, 2], r}, {f, m1, m2, ρ}, UnitSystem -> #]& /@ naturalunits;Compare how the formulas look under different natural unit systems: Grid[Prepend[Transpose[{naturalunits, gravity, coulomb}], {"unit system", "gravitational force", "electrostatic force"}], Dividers -> Center]Related GuidesHistory
Wolfram Research (2018), NondimensionalizationTransform, Wolfram Language function, https://reference.wolfram.com/language/ref/NondimensionalizationTransform.html.
TextWolfram Research (2018), NondimensionalizationTransform, Wolfram Language function, https://reference.wolfram.com/language/ref/NondimensionalizationTransform.html. CMSWolfram Language. 2018. "NondimensionalizationTransform." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/NondimensionalizationTransform.html. APAWolfram Language. (2018). NondimensionalizationTransform. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/NondimensionalizationTransform.html BibTeX@misc{reference.wolfram_2026_nondimensionalizationtransform, author="Wolfram Research", title="{NondimensionalizationTransform}", year="2018", howpublished="\url{https://reference.wolfram.com/language/ref/NondimensionalizationTransform.html}", note=[Accessed: 12-November-2026]} BibLaTeX@online{reference.wolfram_2026_nondimensionalizationtransform, organization={Wolfram Research}, title={NondimensionalizationTransform}, year={2018}, url={https://reference.wolfram.com/language/ref/NondimensionalizationTransform.html}, note=[Accessed: 12-November-2026]} | |||||||||||||||||||||||||||||||
| You are visitor 01402503 — GeezerVison does not store the pages you look up. Best viewed with Netscape Navigator 4.7 or Internet Explorer 6 at 800×600. No cookies required. |