GV

GeezerVison

The World Wide Web, restored to 800 pixels of glory.

Home|About|Gaming cabinet|Archives|How it works|Starter sites

On this site

  • WOLFRAM
  • Products
  • AI AccessUse with Mathematica and Wolfram|One
  • Finance Platform
  • Wolfram|Alpha Notebook Edition
  • Application Server
  • Enterprise Private Cloud
  • Wolfram Engine
  • Wolfram Player
  • Wolfram Cloud App
  • Wolfram Player App
  • Wolfram|Alpha Website
  • Wolfram|Alpha APIs
  • Wolfram AI Ecosystem

This view

  • Original page
  • New address

GeezerVison is showing reference.wolfram.com — QuantityVariableDimensions—Wolfram Documentation

QuantityVariableDimensions[quantityvariable]

returns a list of base dimensions associated with the specified quantityvariable.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Applications  
Properties & Relations  
Possible Issues  
Neat Examples  
See Also
Related Guides
History
Cite this Page

QuantityVariableDimensions

QuantityVariableDimensions[quantityvariable]

returns a list of base dimensions associated with the specified quantityvariable.

Details

  • QuantityVariableDimensions returns a list of ordered dimension pairs, indicating the magnitude of the quantityvariable in that physical dimension.
  • quantityvariable can be a QuantityVariable, a combination of QuantityVariable objects, or the Derivative of a QuantityVariable. quantityvariable can also include "PhysicalQuantity" entities.
  • Physical dimensions include: "AmountUnit", "AngleUnit", "ElectricCurrentUnit", "InformationUnit", "LengthUnit", "LuminousIntensityUnit", "MassUnit", "MoneyUnit", "SolidAngleUnit", "TemperatureDifferenceUnit", "TemperatureUnit", and "TimeUnit".
  • Electromagnetic dimensions follow the SI convention.

Examples

open all close all

Basic Examples  (2)

Find the physical dimensions of a QuantityVariable:

Wolfram Language code: QuantityVariableDimensions[QuantityVariable["Φ", "RadiantFluxDensity"]]

Use the single-argument form of QuantityVariable:

Wolfram Language code: QuantityVariableDimensions[QuantityVariable["RadiantFluxDensity"]]
Wolfram Language code: QuantityVariableDimensions[QuantityVariable["ElectricPotential"]]
Wolfram Language code: QuantityVariableDimensions[QuantityVariable["Temperature"]]

Scope  (3)

Find the physical dimensions of a combination of QuantityVariable objects:

Wolfram Language code: QuantityVariableDimensions[QuantityVariable["RadiantFluxDensity"] ^ 2]
Wolfram Language code: QuantityVariableDimensions[QuantityVariable["RadiantFluxDensity"] ^ 2 / QuantityVariable["Time"]]

Determine the physical dimensions of the Derivative of a QuantityVariable:

Wolfram Language code: QuantityVariableDimensions[QuantityVariable["RadiantFluxDensity"]'[QuantityVariable["Time"]]]
Wolfram Language code: QuantityVariableDimensions[QuantityVariable["RadiantFluxDensity"]''[QuantityVariable["Time"]]]

Discover the dimensions of an arbitrary combination of QuantityVariable objects and their derivatives:

Wolfram Language code: QuantityVariableDimensions[QuantityVariable["RadiantFluxDensity"]''[QuantityVariable["Time"]] / QuantityVariable["Speed"]]

Applications  (2)

Find the dimensional coefficients of a sampling of electrical physical quantities:

Wolfram Language code: pqs = {#, QuantityVariableDimensions[QuantityVariable[#]]}& /@ {"ElectricCapacitance", "ElectricConductivity", "ElectricCurrent", "ElectricPotential", "ElectricResistance", "ElectricResistivity", "MagneticInductance", "MagneticInduction"}; Grid[Prepend[Flatten[{First[#], {Cases[Last[#], {"ElectricCurrentUnit", x_} :> x], Cases[Last[#], {"LengthUnit", x_} :> x], Cases[Last[#], {"MassUnit", x_} :> x], Cases[Last[#], {"TimeUnit", x_} :> x]} /. {} -> 0}]& /@ pqs, {"Physical Quantities", "Current", "Length", "Mass", "Time"}], Frame -> All]

Check equations for dimensional consistency:

Wolfram Language code: FormulaData["NewtonsLawOfUniversalGravitation"]
Wolfram Language code: qv = {#, QuantityVariableDimensions[#]}& /@ FormulaData["NewtonsLawOfUniversalGravitation", "QuantityVariables"]

Define the variables in a standard format based on their dimensions:

Wolfram Language code: mass = {{"LengthUnit", 0}, {"MassUnit", 1}, {"TimeUnit", 0}}; distance = {{"LengthUnit", 1}, {"MassUnit", 0}, {"TimeUnit", 0}}; force = {{"LengthUnit", 1}, {"MassUnit", 1}, {"TimeUnit", -2}};

Check that the formula is dimensionally correct:

Wolfram Language code: force === UnitDimensions[Quantity[1, "GravitationalConstant"]] + 2 * mass - 2 * distance

Properties & Relations  (2)

The dimensions of "PhysicalQuantity" entities can also be determined:

Wolfram Language code: QuantityVariableDimensions[Entity["PhysicalQuantity", "Length"]]

Use the ResourceFunction "PhysicalQuantityLookup" to find physical quantities from unit dimensions:

Wolfram Language code: ResourceFunction["PhysicalQuantityLookup"][{{"LengthUnit", -1}, {"LuminousIntensityUnit", 1}}, "QuantityVariableName"]

Possible Issues  (2)

Some physical quantities are dimensionless:

Wolfram Language code: QuantityVariableDimensions[QuantityVariable["ϵ", "MultiplicativeConstants"]]

For functions of QuantityVariable, dimensions are only returned for the head:

Wolfram Language code: QuantityVariableDimensions[x[t]]

Find the dimensions of derivatives:

Wolfram Language code: QuantityVariableDimensions[QuantityVariable["E", "Energy"]'[QuantityVariable["t", "Time"]]]

Neat Examples  (2)

Explore the space of common physical quantities of mechanics:

Wolfram Language code: mechanicspqs = {#, QuantityVariableDimensions[QuantityVariable[#]]}& /@ {"AngularMomentum", "Energy", "Force", "Frequency", "GravitationalAcceleration", "Length", "Mass", "MassDensity", "MomentOfInertia", "Period", "Power", "Speed", "SpringConstant", "Stress", "Time", "Volume"}; mechanicsdimensions = ({#[[1]], {"LengthUnit", "MassUnit", "TimeUnit"} /. MapThread[Rule, Transpose[#[[2]]]]}& /@ mechanicspqs) /. {"LengthUnit" -> 0, "MassUnit" -> 0, "TimeUnit" -> 0}; Graphics3D[{PointSize[Medium], Blue, Tooltip[Point[#[[2]]], #[[1]]]& /@ mechanicsdimensions}, Axes -> True, Ticks -> Table[i, {3}, {i, -3, 3}], AxesLabel -> {"length", "mass", "time"}, BoxRatios -> 1]

Estimating the power of a bomb blast based on dimensional analysis, using only these physical quantities:

Wolfram Language code: pqs = {QuantityVariable["Energy"], QuantityVariable["MassDensity"], QuantityVariable["Radius"], QuantityVariable["Time"]};

Find the dimensions of these physical quantities:

Wolfram Language code: pqdimensions = {#, QuantityVariableDimensions[#]}& /@ pqs;
Wolfram Language code: Grid[Prepend[Flatten[{First[#], {Cases[Last[#], {"LengthUnit", x_} :> x], Cases[Last[#], {"MassUnit", x_} :> x], Cases[Last[#], {"TimeUnit", x_} :> x]} /. {} -> 0}]& /@ pqdimensions, {"Physical Quantities", "LengthUnit", "MassUnit", "TimeUnit"}], Frame -> All]

Write dimensional equations for the physical quantities involved:

Wolfram Language code: dimensionrules = (#1 -> Times @@((Power@@@#2)))& @@@ pqdimensions

Make an ansatz for the energy as a function of radius, mass, time, and mass density:

Wolfram Language code: energyansatz = QuantityVariable["Energy"] == constant QuantityVariable["MassDensity"] ^ β QuantityVariable["Radius"] ^ γ QuantityVariable["Time"] ^ δ

Form and solve linear equations for the exponents:

Wolfram Language code: PowerExpand[Log /@ (energyansatz /. dimensionrules)]
Wolfram Language code: SolveAlways[%, {Log["LengthUnit"], Log["TimeUnit"], Log["MassUnit"]}]
Wolfram Language code: energyansatz /. First[%]

Given the inputs of the parameters at a given time, estimate the energy of an explosion:

Wolfram Language code: constant = 1; massdensity = Quantity[1.2, "Kilograms" / "Meters" ^ 3]; radius = Quantity[80, "Meters"]; time = Quantity[0.006, "Seconds"];
Wolfram Language code: energy = (constant massdensity radius^5/time^2)
Wolfram Language code: UnitConvert[energy, "KilotonsOfTNT"]

See Also

QuantityVariable  QuantityVariablePhysicalQuantity  QuantityVariableCanonicalUnit  NondimensionalizationTransform

Related Guides

    ▪
  • Units & Quantities
    • ▪
  • Formulas

History

Introduced in 2014 (10.0) | Updated in 2018 (11.3)

Wolfram Research (2014), QuantityVariableDimensions, Wolfram Language function, https://reference.wolfram.com/language/ref/QuantityVariableDimensions.html (updated 2018).

Text

Wolfram Research (2014), QuantityVariableDimensions, Wolfram Language function, https://reference.wolfram.com/language/ref/QuantityVariableDimensions.html (updated 2018).

CMS

Wolfram Language. 2014. "QuantityVariableDimensions." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2018. https://reference.wolfram.com/language/ref/QuantityVariableDimensions.html.

APA

Wolfram Language. (2014). QuantityVariableDimensions. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/QuantityVariableDimensions.html

BibTeX

@misc{reference.wolfram_2026_quantityvariabledimensions, author="Wolfram Research", title="{QuantityVariableDimensions}", year="2018", howpublished="\url{https://reference.wolfram.com/language/ref/QuantityVariableDimensions.html}", note=[Accessed: 12-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_quantityvariabledimensions, organization={Wolfram Research}, title={QuantityVariableDimensions}, year={2018}, url={https://reference.wolfram.com/language/ref/QuantityVariableDimensions.html}, note=[Accessed: 12-November-2026]}
Top
You are visitor 01402503 — GeezerVison does not store the pages you look up.
Best viewed with Netscape Navigator 4.7 or Internet Explorer 6 at 800×600. No cookies required.